コメント
コメントの投稿
※名前とタイトルが入力されていないコメントでは他のコメントとの区別ができません。
入力されていないコメントには返信しませんのであらかじめご了承くださいませ。
令和元号に対応する動的な元号の取得方法 | VB.NET
- 2019/04/02
- 22:18
先日新しい元号である「令和」が発表になりました。そこで、今まで様々な開発現場で 元号のリストが DB やコンフィグファイルに保持されていたり、最悪はVBコードにハードコーティングされている残念なコードを目の当たりにしてきました経緯がありますので、今回の改定を機に元号の名称やリストを自動的に取得できるコードをご紹介したいと思います。元号を自前で保持すると、開発者によるメンテナンスが必須となってしまいますのでよろしくないですね。ハードコート撲滅運動の一環です。
前提条件
Windows 7 professional 以降 / Windows Server 2008 R2 以降
Visual Studio 2010 professional 以降
VB.net
.Net FrameWork 4.0 以降
１．JapaneseCalendar
元号を取得するには JapaneseCalendar を使用します。手順としては以下のようになります。 連番や Distinct に Linq を使用していますので、プロジェクトにSystem.Xml.Linq の参照設定が必要です。（１）1901年から現在までの年のリストを取得し、年の降順に並べかえます。
（２）120年程の年リスト全てに対して元号を取得します。
（３）元号のリストをDistinctします。
CalendarUtility.vb
Imports System.Globalization
Namespace Library
Public Class CalendarUtility
''' <summary>
''' 全ての元号一覧を取得する
''' </summary>
''' <returns></returns>
Public Shared Function GetEraNameList() As List(Of String)
Dim calendar As New JapaneseCalendar()
Dim culture = New System.Globalization.CultureInfo("ja-JP", False)
culture.DateTimeFormat.Calendar = calendar
Dim dtNow As DateTime = DateTime.Now
'（１）1901年から現在までの年のリストを取得し、年の降順に並べかえます。
'（２）120年程の年リスト全てに対して元号を取得します。
'（３）元号のリストをDistinctします。
Return Enumerable.Range(1901, dtNow.Year - 1901) _
.OrderByDescending(Function(r) r) _
.Select(Function(r)
Return New DateTime(r, _
dtNow.Month, _
dtNow.Day) _
.ToString("gg", culture)
End Function) _
.Distinct _
.ToList()
End Function
''' <summary>
''' 日付に対する元号を取得する
''' </summary>
''' <returns></returns>
Public Shared Function GetEraName(ByVal pDate As DateTime) As String
Dim calendar As New JapaneseCalendar()
Dim culture = New System.Globalization.CultureInfo("ja-JP", False)
culture.DateTimeFormat.Calendar = calendar
Return pDate.ToString("gg", culture)
End Function
End Class
End Namespace
２．使用方法
以下の例は asp.net ですが、現在の日付から元号を取得するコードと、全ての元号のデータを DropDownList にデータバインドしています。EraTest.vb
Public Class EraTest
Inherits System.Web.UI.Page
Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
If Not Me.IsPostBack Then
'元号をリテラルにセット
Me.ltrEraName.Text = CalendarUtility.GetEraName(DateTime.Now)
'元号の一覧をDropDownListにセット
Me.ddlEraList.DataSource = CalendarUtility.GetEraNameList()
Me.ddlEraList.DataBind()
'元号リストにIntegerタイプの値（Value）を設定したい場合は、以下のようにListItemの配列をDDLに追加します。
Dim i As Integer = 0
Me.ddlEraList.Items.Clear()
Me.ddlEraList.Items.AddRange( _
CalendarUtility.GetEraNameList().Select(Function(r)
i += 1
Return New ListItem(r, i.ToString)
End Function).ToArray() _
)
End If
End Sub
End Class
以上で 元号の名称やリストをハードコーティングすることなくセットできます。あとは Windows Update によって新しい元号「令和」という定義が更新されることを待つだけですね。
最後までお読みいただき、ありがとうございます。
他にも VB.net に関する記事 をご紹介しておりますのでご参考頂ければ幸いです。
IN 句と EXISTS 句で実行速度が速いのはどちらの方か検証してみました | SQL Server ホーム
初心者が DJI Mavic Air を購入して使用してみましたのでレビューを投稿します | ドローン
