コメント
コメントの投稿
※名前とタイトルが入力されていないコメントでは他のコメントとの区別ができません。
入力されていないコメントには返信しませんのであらかじめご了承くださいませ。
XMLデータから配列を含むクラスに変換する方法 -デシリアライズ- | VB.NET
- 2018/08/01
- 20:11
今回は VB.NET で XML に書かれている配列型のデータをオリジナルのクラスに変換してデータ保持する方法について覚え書きします。
Json を使用すると簡単に実現可能ですが、不要な DLL を参照することになりますし、何かあった時の為にできるだけ外部 DLL には頼らないほうが良いと考えていますので、今回のコードは全て .Net のマネージコードなので、汎用性が高いものと考えています。
前提条件
Windows 7 professional 以降 / Windows Server 2008 R2 以降
Visual Studio 2010 professional 以降
VB.net
.Net FrameWork 4.0 以降
１．XMLファイルの構造
XMLファイルの中にはヘッダーと明細の部分を持たせて、今回は明細部分が List 型で取得できるように想定しました。XmlSample.xml
<?xml version="1.0" encoding="utf-8"?>
<root>
<header>
<id>1</id>
<title>ヘッダー１</title>
</header>
<details>
<detail>
<id>1</id>
<seq>1</seq>
<name>明細１</name>
</detail>
<detail>
<id>1</id>
<seq>2</seq>
<name>明細２</name>
</detail>
<detail>
<id>1</id>
<seq>3</seq>
<name>明細３</name>
</detail>
</details>
</root>
２．ViewModelクラス
XML のデータを保持するためのクラスを作成します。ポイントとしては、変換するオブジェクトのクラス名に XmlRoot の属性を設定し、値に最上位のタグの名称を設定します。
配列となるオブジェクトには XmlArray (”配列のタグ名”) と XmlArrayItem ("配列の元となるタグ名") を設定します。
XmlRoot.vb
<System.Xml.Serialization.XmlRoot("root")>
Public Class XmlSampleClass
<System.Xml.Serialization.XmlElement("header")>
Public Property Header As XmlHeader
<System.Xml.Serialization.XmlArray("details"),
System.Xml.Serialization.XmlArrayItem("detail")>
Public Property Details As List(Of XmlDetail)
End Class
<System.Xml.Serialization.XmlType("header")>
Public Class XmlHeader
<System.Xml.Serialization.XmlElement("id")>
Public Property id As Integer
<System.Xml.Serialization.XmlElement("title")>
Public Property title As String
End Class
<System.Xml.Serialization.XmlType("detail")>
Public Class XmlDetail
<System.Xml.Serialization.XmlElement("id")>
Public Property id As Integer
<System.Xml.Serialization.XmlElement("seq")>
Public Property seq As Integer
<System.Xml.Serialization.XmlElement("name")>
Public Property [name] As String
End Class
この設定がXMLと相違がある場合は、以下のようなエラーが発生しますので、注意が必要です。
型 'System.InvalidOperationException' のハンドルされていない例外が System.Xml.dll で発生しました
{"XML ドキュメント (2,2) でエラーが発生しました。"}
{"<details xmlns=''> は指定できません。"}
３．XMLファイルを開く
StreamReader でファイルを開き、シリアライザーで逆シリアライズしたオブジェクトを取得します。XmlUtility.vb
Public Class XmlUtility
''' <summary>
''' Xmlを読み取り、クラスに変換して返す
''' </summary>
''' <typeparam name="T">変換後の型</typeparam>
''' <param name="filePath">Xmlファイルパス</param>
''' <returns></returns>
Public Shared Function GetObject(Of T)(ByVal filePath As String) As T
'読み込む型を指定します。
Dim tp As Type = GetType(T)
'XmlSerializerオブジェクトを作成
Dim serializer As New System.Xml.Serialization.XmlSerializer(tp)
'UTF指定で開きます
Dim encode As System.Text.Encoding = New System.Text.UTF8Encoding(False)
'読み込むファイルを開く
Dim sr As New System.IO.StreamReader(filePath, encode)
'XMLファイルから読み込み、逆シリアル化する
Dim obj As T = DirectCast(serializer.Deserialize(sr), T)
'XMLファイルを閉じる
sr.Close()
Return obj
End Function
End Class
４．使用方法
以下のように XmlUtility を呼び出し、変数に格納します。TestForm.vb
Private Sub btnReadXml_Click(ByVal sender As Object, ByVal e As EventArgs) Handles btnReadXml.Click
Dim obj As XmlSampleClass = XmlUtility.GetObject(Of XmlSampleClass)("c:\XmlSample.xml")
End Sub
以上で XML ファイルの中のデータをクラスに保持し、そのクラス内に配列も保持することができています。
最後までお読みいただき、ありがとうございます。
他にも VB.net に関する記事 をご紹介しておりますのでご参考頂ければ幸いです。
- 関連記事
-
- データセットに複数列のリレーションを追加する方法 | VB.NET
- JSON形式の文字列データをクラスに変換する方法 -デシリアライズ- | VB.NET
- XMLデータから配列を含むクラスに変換する方法 -デシリアライズ- | VB.NET
- FtpWebRequestを使用する際の注意点 | VB.NET
- FTP接続時に Cannot access a disposed object. のエラーが発生する件 | FtpWebRequest
